Instrucciones

Cada instrucción de un programa debe escribirse en una línea diferente. Es decir, hay que pulsar Intro al terminar de escribir cada instrucción.

Representación gráfica de la parábola $y=x^2-2x+1$ y la recta $y=x+1$ en el intervalo $(-2,4)$.

xxxxxxxxxx

parabola = plot(x^2 - 2*x + 1, xmin=-2, xmax=4, color='cadetblue')

recta = plot(x + 1, xmin=-2, xmax=4, color='brown')

​

show(parabola + recta, gridlines=True)

Variables

Las variables hay que declararlas antes de utilizarlas. La variable x, sin embargo, no es necesario declararla.

Resolución del sistema de ecuaciones: $\begin{array}{c}{x}^2+y^2=2\\ 2x+2y=3\end{array}\}$.

xxxxxxxxxx

var('y')

​

ecuacion1 = x^2 + y^2 == 2

ecuacion2 = 2*x + 2*y == 3

​

solucion = solve([ecuacion1, ecuacion2], x, y)

​

show(solucion)

Comentarios

Las instrucciones que comienzan con el símbolo # son comentarios, y no se ejecutan.

Representación gráfica en tres dimensiones de la hélice: $\begin{array}{c}x=2\cos t\\ y=2\mathrm{sen}t\\ z=\frac{t}{4}\end{array}\}$ para $t\in (0,4\pi )$.

xxxxxxxxxx

var('t')

​

# Ecuaciones paramétricas de la hélice

x = 2*cos(t)

y = 2*sin(t)

z = t/4

​

# Gráfica de la hélice     

helice = parametric_plot3d((x,y,z), (t,0,4*pi))

​

# Salida por pantalla

show(helice)

Mayúsculas

Sage es un lenguaje case sensitive. Es decir, distingue mayúsculas de minúsculas.

Círculo de centro $(1,1)$ y radio $1$, y circunferencia de centro $(2,2)$ y radio $2$.

xxxxxxxxxx

# Círculo

centro = (1,1)

radio = 1

circulo = circle(centro, radio, fill=True)

​

# Circunferencia

Centro = (2,2)

Radio = 2

circunferencia = circle(Centro, Radio)

​

# Salida por pantalla

show(circulo + circunferencia)

Funciones

Las funciones de Sage necesitan paréntesis. Dentro de los paréntesis van los argumentos de la función, que se separan mediante comas. Si la función no necesita argumentos, los paréntesis van vacíos.

Límites de la función $f\left(x\right)=\frac{x-1}{x+1}$ cuando $x$ tiende a $-1$ y cuando $x$ tiende a $+\infty$.

xxxxxxxxxx

f(x)=(x-1)/(x+1)

​

# Límites cuando x tiende a -1

limite_izq = limit(f(x), x=-1, dir='-')

limite_der = limit(f(x), x=-1, dir='+')

​

# Límites cuando x tiende a infinito

limite_masInf = limit(f(x), x=oo)

limite_menosInf = limit(f(x), x=-oo)

​

# Salida por pantalla

show("f(x)=", f(x))

show("Límite cuando x tiende a -1 por la izquierda:", limite_izq)

show("Límite cuando x tiende a -1 por la derecha:", limite_der)

show("Límite cuando x tiende a más infinito:", limite_masInf)

show("Límite cuando x tiende a menos infinito:", limite_menosInf)

Listas

Los elementos que pertenecen a una lista se escriben dentro de corchetes.

Representación del baricentro del triángulo de vértices $A(-1,2)$, $B(2,-3)$ y $C(4,3)$.

xxxxxxxxxx

# Coordenadas del vértice A

xA = -1

yA = 2

A = (xA,yA)

​

# Coordenadas del vértice B

xB = 2

yB = -3

B = (xB,yB)

​

# Coordenadas del vértice C

xC = 4

yC = 3

C = (xC,yC)

​

# Coordenadas del baricentro G

xG = (xA + xB + xC)/3

yG = (yA + yB + yC)/3

G = (xG,yG)

​

# Baricentro

baricentro = point(G, size=50, color='crimson')

​

# Vértices

vertices = point([A,B,C], color='black')

​

# Lados

lados = line([A,B,C,A], color='darkslategray')

​

# Salida por pantalla

show(baricentro + vertices + lados, gridlines=True)

Bloques

En general no se debe dejar ningún espacio en blanco antes de una instrucción. Sin embargo, para agrupar varias instrucciones en un bloque estas se deben indentar con cuatro espacios (un tabulador).

Cálculo de seno, coseno y tangente de los ángulos $0^{\circ }$, ${30}^{\circ }$, ${45}^{\circ }$, ${60}^{\circ }$ y ${90}^{\circ }$.

xxxxxxxxxx

for angulo in [0, 30, 45, 60, 90]:

    angulo_rad = angulo*pi/180       # Ángulo a radianes

    print("Ángulo:", angulo, "grados")

    print("-----------------")

    print("Seno:", sin(angulo_rad))

    print("Coseno:", cos(angulo_rad))

    print("Tangente:", tan(angulo_rad))

    print()

Recuerda que es necesario que sigas estas reglas para evitar errores cuando estés escribiendo tus programas.